Home vs. Rebol Home

[rgchris]

In looking in these lines in %sys-start.reb, I wonder if it might be better separating the ideas of HOME and REBOL_HOME.

• HOME should be, where appropriate, the home folder of the user.

• REBOL_HOME should be where to find modules and other script-related things.

I think that it's fine that REBOL_HOME defaults to HOME + .rebol, however I don't know that it's useful inferring HOME based on a REBOL_HOME value—rather REBOL_HOME should only override the HOME + .rebol part. A few issues with this—1) I'm not sure it's a good thing pretending a user has a home folder when they don't, 2) wherever REBOL_HOME points to requires an additional .rebol folder which can get messy, and 3) it creates confusion over where user.reb should be (and becomes a visible file in the user's home folder if that's where the path resolves to).

I'd propose these changes:

;-  3. /home - preferably one of environment variables
;
home: dirize to-rebol-file any [
    get-env "HOME"        ; Default user's home directory on Linux
    get-env "USERPROFILE" ; Default user's home directory on Windows
]

;- 4. /data - directory of any application data (modules, cache...)
;
data: case [
    get-env "REB_HOME" [
        case [
            exists? data: dirize to-rebol-file get-env "REB_HOME" [
                data
            ]

            ; assuming that a data folder MUST exist
            ;
            not error? try [
                make-dir/deep data
            ][
                data
            ]

            'else [
                sys/log/error 'REBOL "Could not establish a data folder"
                none
            ]
        ]
    ]

    either 'Windows = system/platform [
        all [
            get-env "APPDATA"
            data: join dirize to-rebol-file get-env "APPDATA" %Rebol/
        ]
    ][
        all [
            home
            data: join home %.rebol/
        ]
    ][
        case [
            exists? data [
                data
            ]

            ; assuming that a data folder MUST exist
            ;
            not error? try [
                make-dir data
            ][
                data
            ]

            'else [
                sys/log/error 'REBOL "Could not establish a data folder"
                none
            ]
        ]
    ]

    'else [
        sys/log/error 'REBOL "Could not locate a data folder"
        none
    ]
]

;- 5. /modules - directory of extension module files
;
modules: case [
    not data [
        sys/log/error 'REBOL "Could not locate a modules folder"
        none
    ]

    exists? modules: join data %modules/ [
        modules
    ]

    ; assuming that a modules folder MUST exist
    ;
    not error? try [
        make-dir modules
    ][
        modules
    ]

    'else [
        sys/log/error 'REBOL "Could not establish a modules folder"
        none
    ]
]

...

sys/log/info 'REBOL [
    "Checking for user.reb file in" data
]

if all [
    data
    exists? data/%user.reb
][
	try/with [
        do data/%user.reb
    ][
        sys/log/error 'REBOL system/state/last-error
    ]
]

This workflow creates clear distinctions between HOME, REBOL_HOME and where to put modules and user.reb

[rgchris]

I pushed a version of SYS-START.REB (and fix) that reflects this suggested change. Apologies for some of the refactoring, mostly done as an exercise to understand the workflow...

(note: I have my clone of the Rebol 3 repo on GitLab only because, as I understand it, I can't host more than one clone of rebolsource/r3 on GitHub, otherwise...)

(see also: #707)

[Oldes]

You are rebolsource admin?

[Oldes]

The refactoring is quite unfortunate, because now it is very hard for me to see, where is the key modification.. When I compare it with the current version, almost everything is in a conflict, so it is not possible to just cherry-pick the commit.

[rgchris]

I can redo as required, will put into a Gist.

[Oldes]

Ok... here is code based on your proposal: 669b390
In my case the modules folder is in a different location, so I hope it will not be too confusing.

[rgchris]

This should help with the CGI issue too—to use as CGI, there only needs to be a data folder (pointed to by REBOL_HOME) and a modules subfolder.

[rgchris]

Some fixes for when there is no "HOME" variable

[Oldes]

Another possible source of confusion may be, that ~ shortcut location is now changed... I used it quite often. Now (in my setup) it does not points to the REBOL_HOME location like before.

[rgchris]

That will be a problem. You could always add a second shortcut location for REBOL_HOME, e.g. ~~. I can't think of any other way to reconcile this.

There will be times (like in the CGI discussion) where REBOL_HOME exists, but HOME does not.